Portail: Clockover.org

Métadonnées du document:
[ Auteur : Clockover ][ Création le : 27/06/2012 ][ Dernière modification le : 27/06/2012 ][ Version : 1.0 ]

Contrôle du bureau d'un utilisateur (verrou complet et déploiement automatique) [VBS]

Etat du script: Fonctionnel

Présentation:

Ce script VBS permet d"empêcher un utilisateur de modifier le contenu de son bureau (supprimer/ajouter un élément) et de déployer simplement des outils à des groupes de personnes. L'usage le plus intéressant est donc lorsqu'il s'agit de sessions Terminal Server.
Il opère en trois temps:
1. Il déverouille la modification du bureau de l'utilisateur courant.
2. Il place ou enlève les icônes ou autre outils nécessaire à l'utilisateur.
3. Il reverrouille la modification sur le bureau.

Ce script fonctionne à l'aide de l'outil en ligne de commande Setacl.exe (disponible directement : ici ou bien sur le site de l'éditeur: ici).

Comme habituellement, il suffit donc d'appliquer ce script par GPO et il est totalement silencieux.

Le script:

'Verrouillage bureau utilisateur et déploiement application
'Version 1.1 20120424 by Clockover

''''' FONCTION '''''
'Vérifier si un utilisateur est membre d'un groupe
Function IsMember (strGroup)
	Set oGroup = GetObject ("WinNT://" & WshNetwork.UserDomain & "/" & strGroup)
	IsMember = oGroup.IsMember ("WinNT://" & WshNetwork.UserDomain & "/" & WshNetWork.UserName)
End Function

''''' MAIN '''''

On Error Resume Next
set WshShell = WScript.CreateObject("WScript.Shell")
set WshFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set WshNetwork = CreateObject ("WScript.Network")

'Déverrouiller le bureau pour procéder aux modifications
WshShell.Run "\\domain.suffix\SysVol\domain.suffix\scripts\setacl.exe -on %userprofile%\Desktop -ot file -actn ace -ace n:%username%;p:add_file,add_subdir,del_child,delete;s:n;i:so,sc;m:grant;w:dacl", 0
'Petite pause pour que Setacl.exe est le temps d'appliquer les changements NTFS
wscript.sleep(2000)														

'Ajouter le raccourci de Outlook 2010
strPath = WshShell.SpecialFolders("Desktop") & "\Microsoft Outlook 2010.lnk" 			
Set oShellLink = WshShell.CreateShortcut(strPath)
oShellLink.TargetPath = "C:\Program Files\Microsoft Office\Office14\Outlook.exe"		
oShellLink.Save	

'Ajouter le raccourci d'une application spécifique si l'utilisateur est membre du groupe nommé "Groupe_AD" (suppression sinon)
strPath = WshShell.SpecialFolders("Desktop") & "\Application diverse.lnk" 
WshFSO.DeleteFile strPath
if isMember("Groupe_AD") then
	Set oShellLink = WshShell.CreateShortcut(strPath)
	oShellLink.TargetPath = "C:\Program Files (x86)\editeur\appli.exe"
	oShellLink.Save	
end if

'Verrouiller le bureau
WshShell.Run "\\domain.suffix\SysVol\domain.suffix\scripts\setacl.exe -on %userprofile%\Desktop -ot file -actn ace -ace n:%username%;p:add_file,add_subdir,del_child,delete;s:n;i:so,sc;m:deny;w:dacl", 0

TODO Liste:

-Vide

Historique:

Version 1.1 (2012/04/24)
-Modification car le déverrouillage ne fonctionnait pas correctement.

Il y a 0 commentaire(s) sur ce sujet.